5 files changed, 100 insertions, 0 deletions
diff --git a/actioncable/test/javascript/src/test.coffee b/actioncable/test/javascript/src/test.coffee
new file mode 100644
index 0000000000..eb95fb2604
--- /dev/null
+++ b/actioncable/test/javascript/src/test.coffee
@@ -0,0 +1,3 @@
+#= require action_cable
+#= require ./test_helpers
+#= require_tree ./unit
diff --git a/actioncable/test/javascript/src/test_helpers/consumer_test_helper.coffee b/actioncable/test/javascript/src/test_helpers/consumer_test_helper.coffee
new file mode 100644
index 0000000000..6b145dede8
--- /dev/null
+++ b/actioncable/test/javascript/src/test_helpers/consumer_test_helper.coffee
@@ -0,0 +1,37 @@
+#= require mock-socket
+
+{TestHelpers} = ActionCable
+
+TestHelpers.consumerTest = (name, options = {}, callback) ->
+  unless callback?
+    callback = options
+    options = {}
+
+  options.url ?= TestHelpers.testURL
+
+  QUnit.test name, (assert) ->
+    doneAsync = assert.async()
+
+    ActionCable.WebSocket = MockWebSocket
+    server = new MockServer options.url
+    consumer = ActionCable.createConsumer(options.url)
+
+    server.on "connection", ->
+      clients = server.clients()
+      assert.equal clients.length, 1
+      assert.equal clients[0].readyState, WebSocket.OPEN
+
+    done = ->
+      consumer.disconnect()
+      server.close()
+      doneAsync()
+
+    testData = {assert, consumer, server, done}
+
+    if options.connect is false
+      callback(testData)
+    else
+      server.on "connection", ->
+        testData.client = server.clients()[0]
+        callback(testData)
+      consumer.connect()
diff --git a/actioncable/test/javascript/src/test_helpers/index.coffee b/actioncable/test/javascript/src/test_helpers/index.coffee
new file mode 100644
index 0000000000..d36524d9cc
--- /dev/null
+++ b/actioncable/test/javascript/src/test_helpers/index.coffee
@@ -0,0 +1,8 @@
+#= require_self
+#= require_tree .
+
+ActionCable.TestHelpers =
+  testURL: "ws://cable.example.com/"
+
+originalWebSocket = ActionCable.WebSocket
+QUnit.testDone -> ActionCable.WebSocket = originalWebSocket
diff --git a/actioncable/test/javascript/src/unit/action_cable_test.coffee b/actioncable/test/javascript/src/unit/action_cable_test.coffee
new file mode 100644
index 0000000000..3944f3a7f6
--- /dev/null
+++ b/actioncable/test/javascript/src/unit/action_cable_test.coffee
@@ -0,0 +1,41 @@
+{module, test} = QUnit
+{testURL} = ActionCable.TestHelpers
+
+module "ActionCable", ->
+  module "Adapters", ->
+    module "WebSocket", ->
+      test "default is window.WebSocket", (assert) ->
+        assert.equal ActionCable.WebSocket, window.WebSocket
+
+      test "configurable", (assert) ->
+        ActionCable.WebSocket = ""
+        assert.equal ActionCable.WebSocket, ""
+
+    module "logger", ->
+      test "default is window.console", (assert) ->
+        assert.equal ActionCable.logger, window.console
+
+      test "configurable", (assert) ->
+        ActionCable.logger = ""
+        assert.equal ActionCable.logger, ""
+
+  module "#createConsumer", ->
+    test "uses specified URL", (assert) ->
+      consumer = ActionCable.createConsumer(testURL)
+      assert.equal consumer.url, testURL
+
+    test "uses default URL", (assert) ->
+      pattern = ///#{ActionCable.INTERNAL.default_mount_path}$///
+      consumer = ActionCable.createConsumer()
+      assert.ok pattern.test(consumer.url), "Expected #{consumer.url} to match #{pattern}"
+
+    test "uses URL from meta tag", (assert) ->
+      element = document.createElement("meta")
+      element.setAttribute("name", "action-cable-url")
+      element.setAttribute("content", testURL)
+
+      document.head.appendChild(element)
+      consumer = ActionCable.createConsumer()
+      document.head.removeChild(element)
+
+      assert.equal consumer.url, testURL
diff --git a/actioncable/test/javascript/src/unit/consumer_test.coffee b/actioncable/test/javascript/src/unit/consumer_test.coffee
new file mode 100644
index 0000000000..cf8a592255
--- /dev/null
+++ b/actioncable/test/javascript/src/unit/consumer_test.coffee
@@ -0,0 +1,11 @@
+{module, test} = QUnit
+{consumerTest} = ActionCable.TestHelpers
+
+module "ActionCable.Consumer", ->
+  consumerTest "#connect", connect: false, ({consumer, server, done}) ->
+    server.on("connection", done)
+    consumer.connect()
+
+  consumerTest "#disconnect", ({consumer, client, done}) ->
+    client.addEventListener("close", done)
+    consumer.disconnect()