From 896950a605c509f19f3e8cbde11e23ca87036ca3 Mon Sep 17 00:00:00 2001
From: Javan Makhmali <javan@javan.us>
Date: Sat, 30 Jan 2016 15:41:14 -0500
Subject: Add task to create precompiled action_cable.js and reorganize to
 accommodate

---
 .../action_cable/source/connection_monitor.coffee  | 79 ++++++++++++++++++++++
 1 file changed, 79 insertions(+)
 create mode 100644 actioncable/lib/assets/javascripts/action_cable/source/connection_monitor.coffee

(limited to 'actioncable/lib/assets/javascripts/action_cable/source/connection_monitor.coffee')

diff --git a/actioncable/lib/assets/javascripts/action_cable/source/connection_monitor.coffee b/actioncable/lib/assets/javascripts/action_cable/source/connection_monitor.coffee
new file mode 100644
index 0000000000..99b9a1c6d5
--- /dev/null
+++ b/actioncable/lib/assets/javascripts/action_cable/source/connection_monitor.coffee
@@ -0,0 +1,79 @@
+# Responsible for ensuring the cable connection is in good health by validating the heartbeat pings sent from the server, and attempting
+# revival reconnections if things go astray. Internal class, not intended for direct user manipulation.
+class ActionCable.ConnectionMonitor
+  @pollInterval:
+    min: 3
+    max: 30
+
+  @staleThreshold: 6 # Server::Connections::BEAT_INTERVAL * 2 (missed two pings)
+
+  identifier: ActionCable.INTERNAL.identifiers.ping
+
+  constructor: (@consumer) ->
+    @consumer.subscriptions.add(this)
+    @start()
+
+  connected: ->
+    @reset()
+    @pingedAt = now()
+    delete @disconnectedAt
+
+  disconnected: ->
+    @disconnectedAt = now()
+
+  received: ->
+    @pingedAt = now()
+
+  reset: ->
+    @reconnectAttempts = 0
+
+  start: ->
+    @reset()
+    delete @stoppedAt
+    @startedAt = now()
+    @poll()
+    document.addEventListener("visibilitychange", @visibilityDidChange)
+
+  stop: ->
+    @stoppedAt = now()
+    document.removeEventListener("visibilitychange", @visibilityDidChange)
+
+  poll: ->
+    setTimeout =>
+      unless @stoppedAt
+        @reconnectIfStale()
+        @poll()
+    , @getInterval()
+
+  getInterval: ->
+    {min, max} = @constructor.pollInterval
+    interval = 5 * Math.log(@reconnectAttempts + 1)
+    clamp(interval, min, max) * 1000
+
+  reconnectIfStale: ->
+    if @connectionIsStale()
+      @reconnectAttempts++
+      unless @disconnectedRecently()
+        @consumer.connection.reopen()
+
+  connectionIsStale: ->
+    secondsSince(@pingedAt ? @startedAt) > @constructor.staleThreshold
+
+  disconnectedRecently: ->
+    @disconnectedAt and secondsSince(@disconnectedAt) < @constructor.staleThreshold
+
+  visibilityDidChange: =>
+    if document.visibilityState is "visible"
+      setTimeout =>
+        if @connectionIsStale() or not @consumer.connection.isOpen()
+          @consumer.connection.reopen()
+      , 200
+
+  now = ->
+    new Date().getTime()
+
+  secondsSince = (time) ->
+    (now() - time) / 1000
+
+  clamp = (number, min, max) ->
+    Math.max(min, Math.min(max, number))
-- 
cgit v1.2.3